**3.53. Свойства**

Подсистема «Свойства» позволяет создавать и редактировать в режиме 1С:Предприятие дополнительные свойства произвольных объектов конфигурации (не внося изменения в саму конфигурацию). При этом дополнительные свойства можно выводить как в списках, так и в отчетах программы, как и обычные реквизиты объектов. Объектами со свойствами могут быть любые объекты ссылочного типа.

Дополнительные свойства объектов могут быть двух видов:

* ● дополнительные реквизиты - это свойства, которые хранятся в самом объекте (в специализированной табличной части). Дополнительные реквизиты являются неотъемлемой частью объекта, вводятся при его редактировании и доступны для редактирования тем же пользователям, которым доступен и сам объект со свойствами. Например, реквизиты вес, размеры, цвет справочника товары.
* ● дополнительные сведения - не являются неотъемлемыми свойствами объекта. Они, как правило, доступны для редактирования тем пользователям, которые не имеют доступа к самому объекту. При внедрении подсистемы совместно с подсистемой «Управление доступом» имеется возможность ограничивать доступ пользователей к отдельным дополнительным сведениям. Например, дата ближайшей поставки товара.

**Настройка**

Перед внедрением подсистемы в конфигурацию необходимо принять решение о составе объектов конфигурации, которые пользователи смогут расширять дополнительными свойствами. В этот список следует включить те объекты, свойства которых с большой вероятностью потребуется определять пользователю. Такими объектами, как правило, являются справочники, которые имеют слишком универсальный характер. Пример – справочник товаров, для которого только при внедрении будет понятна востребованность таких свойств, как вес, размеры, цвет и т. д.

После чего выбрать, какие виды дополнительных свойств необходимы в выбранных объектах:

* ● только дополнительные реквизиты,
* ● только дополнительные сведения,
* ● дополнительные свойства обоих типов.

Затем необходимо принять решение по поводу доступных (для выбора пользователем) типов значений дополнительных свойств и перечислить их в свойстве Тип плана видов характеристик ДополнительныеРеквизитыИСведения. При работе пользователь сможет создавать дополнительные свойства таких типов для всех объектов, в которых будет внедрена подсистема «Свойства». Как правило, в этот список включаются некоторые справочники и перечисления конфигурации. Не рекомендуется включать в состав типов дополнительных свойств такие объекты, как документы, задачи, бизнес-процессы и пр. Также не рекомендуется избыточно расширять состав типов значений дополнительных свойств, т. к. это приведет к усложнению настройки системы пользователем.

**Настройка объектов с дополнительными реквизитами**

1. Создать табличную часть ДополнительныеРеквизиты с реквизитами:

Таблица 3.107.

| Имя | Тип | Подсказка |
| --- | --- | --- |
| Свойство | ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения | Дополнительный реквизит |
| Значение | Характеристика.ДополнительныеРеквизитыИСведения | Значение дополнительного реквизита |
| ТекстоваяСтрока | Строка неограниченной длины | Полный текст строкового дополнительного реквизита |

Реквизиту Значение в свойстве Связи параметров выбора установить связь: Отбор.Владелец (ДополнительныеРеквизиты.Свойство).

2. В форме объекта рекомендуется создать специальную группу полей или страницу с наименованием ГруппаДополнительныеРеквизиты для размещения элементов управления, редактирующих свойства объекта.

3. В обработчике события ПриСозданииНаСервере формы объекта необходимо выполнить вызов:

// СтандартныеПодсистемы.Свойства

ДополнительныеПараметры = Новый Структура;

ДополнительныеПараметры.Вставить("ИмяЭлементаДляРазмещения", "ГруппаДополнительныеРеквизиты");

УправлениеСвойствами.ПриСозданииНаСервере(ЭтотОбъект, ДополнительныеПараметры);

// Конец СтандартныеПодсистемы.Свойства

где ГруппаДополнительныеРеквизиты – имя группы формы, созданной на шаге 2, в которой будут располагаться поля формы, предназначенные для редактирования дополнительных реквизитов. Если этот параметр не указывать, то элементы управления для редактирования свойств будут размещаться в нижней части формы.

В некоторых случаях возникает необходимость размещать дополнительные реквизиты в разных местах формы, например, когда в форме с несколькими страницами на каждой из них выводится свой набор свойств. В таком случае в параметр ИмяЭлементаДляРазмещения необходимо передать список значений, где значение - ссылка на предопределенный набор свойств, а представление - имя группы формы, в которую выводить его реквизиты. Например:

СправочникНаборы = Справочники.НаборыДополнительныхРеквизитовИСведений;

ГруппыДляРазмещения = Новый СписокЗначений;

ГруппыДляРазмещения.Добавить(СправочникНаборы.Справочник\_ДемоКонтрагенты\_Основное, Элементы.ГруппаОсновное.Имя);

ГруппыДляРазмещения.Добавить("ВсеОстальные", Элементы.ГруппаПрочее.Имя);

ДополнительныеПараметры = Новый Структура;

ДополнительныеПараметры.Вставить("ИмяЭлементаДляРазмещения", ГруппыДляРазмещения);

УправлениеСвойствами.ПриСозданииНаСервере(ЭтотОбъект, ДополнительныеПараметры);

Значение ВсеОстальные в группах для размещения указывает, куда выводить дополнительные реквизиты тех наборов, которые не перечислены в данном списке.

При использования формы для работы с разными объектами следует передать параметр ПроизвольныйОбъект со значением Истина и в дальнейшем вызывать процедуру ОбновитьЭлементыДополнительныхРеквизитов для разных объектов.

4. В модуле формы каждого объекта со свойствами необходимо добавить процедуру:

#Область ОбработчикиКомандФормы

...

// СтандартныеПодсистемы.Свойства

&НаКлиенте

Процедура Подключаемый\_СвойстваВыполнитьКоманду(ЭлементИлиКоманда, НавигационнаяСсылка = Неопределено, СтандартнаяОбработка = Неопределено)

УправлениеСвойствамиКлиент.ВыполнитьКоманду(ЭтотОбъект, ЭлементИлиКоманда, СтандартнаяОбработка);

КонецПроцедуры

// Конец СтандартныеПодсистемы.Свойства

#КонецОбласти

5. В обработчике события ПриОткрытии добавить код:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствамиКлиент.ПослеЗагрузкиДополнительныхРеквизитов(ЭтотОбъект);

// Конец СтандартныеПодсистемы.Свойства

6. В обработчике события ОбработкаОповещения добавить код:

// СтандартныеПодсистемы.Свойства

Если УправлениеСвойствамиКлиент.ОбрабатыватьОповещения(ЭтотОбъект, ИмяСобытия, Параметр) Тогда

ОбновитьЭлементыДополнительныхРеквизитов();

УправлениеСвойствамиКлиент.ПослеЗагрузкиДополнительныхРеквизитов(ЭтотОбъект);

КонецЕсли;

// Конец СтандартныеПодсистемы.Свойства

7. Добавить вспомогательные процедуры:

#Область СлужебныеПроцедурыИФункции

// СтандартныеПодсистемы.Свойства

&НаСервере

Процедура ОбновитьЭлементыДополнительныхРеквизитов()

УправлениеСвойствами.ОбновитьЭлементыДополнительныхРеквизитов(ЭтотОбъект);

КонецПроцедуры

&НаКлиенте

Процедура ОбновитьЗависимостиДополнительныхРеквизитов()

УправлениеСвойствамиКлиент.ОбновитьЗависимостиДополнительныхРеквизитов(ЭтотОбъект);

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_ПриИзмененииДополнительногоРеквизита(Элемент)

УправлениеСвойствамиКлиент.ОбновитьЗависимостиДополнительныхРеквизитов(ЭтотОбъект);

КонецПроцедуры

// Конец СтандартныеПодсистемы.Свойства

#КонецОбласти

8. В обработчике события ПриЧтенииНаСервере добавить код:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствами.ПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект);

// Конец СтандартныеПодсистемы.Свойства

9. В обработчике события ОбработкаПроверкиЗаполненияНаСервере добавить код:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствами.ОбработкаПроверкиЗаполнения(ЭтотОбъект, Отказ, ПроверяемыеРеквизиты);

// Конец СтандартныеПодсистемы.Свойства

10. В обработчике события ПередЗаписьюНаСервере добавить код:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствами.ПередЗаписьюНаСервере(ЭтотОбъект, ТекущийОбъект);

// Конец СтандартныеПодсистемы.Свойства

**Настройка отложенной инициализации дополнительных реквизитов**

Дополнительные реквизиты, расположенные на отдельной странице (закладке) формы, необходимо загружать отложенно. Это позволит существенно ускорить открытие форм.

Важно!

При отложенной инициализации будет невозможно выполнить перемещение дополнительных реквизитов при помощи команды Изменить форму из группы, в которой они расположены.

1. В обработчике события ПриСозданииНаСервере формы объекта, в блоке кода:

// СтандартныеПодсистемы.Свойства

ДополнительныеПараметры = Новый Структура;

ДополнительныеПараметры.Вставить("ИмяЭлементаДляРазмещения", "ГруппаДополнительныеРеквизиты");

УправлениеСвойствами.ПриСозданииНаСервере(ЭтотОбъект, ДополнительныеПараметры);

// Конец СтандартныеПодсистемы.Свойства

дополнить структуру новым параметром ОтложеннаяИнициализация:

ДополнительныеПараметры.Вставить("ОтложеннаяИнициализация", Истина);

2. В обработчике ПриСменеСтраницы группы страниц, в которой выводятся дополнительные реквизиты, добавить код:

// СтандартныеПодсистемы.Свойства

Если ЭтотОбъект.ПараметрыСвойств.Свойство(ТекущаяСтраница.Имя)

И Не ЭтотОбъект.ПараметрыСвойств.ВыполненаОтложеннаяИнициализация Тогда

СвойстваВыполнитьОтложеннуюИнициализацию();

УправлениеСвойствамиКлиент.ПослеЗагрузкиДополнительныхРеквизитов(ЭтотОбъект);

КонецЕсли;

// Конец СтандартныеПодсистемы.Свойства

3. Добавить вспомогательную процедуру:

#Область СлужебныеПроцедурыИФункции

&НаСервере

Процедура СвойстваВыполнитьОтложеннуюИнициализацию()

УправлениеСвойствами.ЗаполнитьДополнительныеРеквизитыВФорме(ЭтотОбъект);

КонецПроцедуры

#КонецОбласти

**Настройка объектов с дополнительными сведениями**

Перечислить типы объектов с дополнительными сведениями в составе определяемого типа ВладелецДополнительныхСведений. Поддерживаемые типы объектов – документы, справочники, планы видов характеристик, планы счетов, планы видов расчета, бизнес-процессы и задачи.

**Настройка динамических списков**

Для возможности отображения дополнительных реквизитов и сведений в формах списков объектов со свойствами необходимо добавить поле Ссылка из запроса динамического списка в таблицу формы, связанную с этим динамическим списком. При этом добавленное поле Ссылка следует по умолчанию скрыть от пользователей, сняв флаг Видимость в свойстве Пользовательская видимость.

**Настройка наборов свойств объектов**

В большинстве случаев достаточно одного набора свойств для объекта метаданных, например, у всех элементов справочника товаров должны быть такие свойства, как вес, размеры, цвет и т.д. Для этого необходимо:

1. В справочнике НаборыДополнительныхРеквизитовИСведений создать предопределенный элемент с именем Справочник\_<ИмяОбъекта>, если объект – справочник; Документ\_<ИмяОбъекта>, если объект – документ, и т. д. Например: Справочник\_Сотрудники, Документ\_АвансовыйОтчет, БизнесПроцесс\_Продажа. Наименование элемента при этом заполнять не требуется (оно будет заполнено автоматически на основании представления списка того объекта, к которому относится данный элемент).

2. Добавить в обработчике обновления информационной базы вызов процедуры УстановитьПараметрыНабораСвойств общего модуля УправлениеСвойствами для заполнения настроек добавленного набора свойств.

**Особые случаи настройки наборов свойств**

**Настройка объектов с разными наборами свойств у разных групп объектов**

В отдельных случаях может быть необходима более гибкая настройка. Например, в зависимости от вида товара у него могут быть уникальные характеристики: у картриджей для принтеров требуется свойство - Тип принтера, а у мебели - Материал.

При этом подходе набор свойств, применяемый для конкретного экземпляра объекта, определяется по группе объектов, содержащей ссылку на набор свойств. В демонстрационной конфигурации этот вариант применения свойств показан на справочнике \_ДемоНоменклатура. В каждом элементе справочника применяется тот или иной набор свойств в зависимости от вида номенклатуры (группы объектов). Справочник \_ДемоНоменклатура имеет реквизит ВидНоменклатуры, и в зависимости от его значения элемент справочника получает тот или иной набор дополнительных свойств, ссылка на который извлекается в объекте справочника \_ДемоВидыНоменклатуры. Для настройки требуется следующее:

1. Создать справочник, значения которого соответствуют разным наборам свойств объекта со свойствами. Например, для справочника \_ДемоНоменклатура в демонстрационной конфигурации это справочник \_ДемоВидыНоменклатуры.

2. В этом справочнике добавить реквизит НаборСвойств типа СправочникСсылка.НаборыДополнительныхРеквизитовИСведений. Включить реквизит в состав функциональной опции (если нет, создать) ИспользоватьДополнительныеРеквизитыИСведения<Имя конфигурации>. Если справочник группирует объекты более чем одного типа, допустимо добавить два и более реквизитов с подходящими именами, например: НаборСвойствОшибок, НаборСвойствЗадач.

3. В обработчике ПередЗаписью модуля объекта этого справочника выполнить вызов УправлениеСвойствами. ПриЗаписиВидаОбъекта и передать туда в качестве параметров записываемый объект и имя набора свойств, например:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствами.ПередЗаписьюВидаОбъекта(ЭтотОбъект, "Справочник\_ДемоНоменклатура");

// Конец СтандартныеПодсистемы.Свойства

Если справочник группирует объекты более чем одного типа, следует сделать два или более вызова, указав имена используемых реквизитов, например:

// СтандартныеПодсистемы.Свойства

УправлениеСвойствами.ПередЗаписьюВидаОбъекта(ЭтотОбъект, "Справочник\_ДемоОшибки","НаборСвойствОшибок");

УправлениеСвойствами.ПередЗаписьюВидаОбъекта(ЭтотОбъект, "Справочник\_ДемоЗадачи","НаборСвойствЗадач");

// Конец СтандартныеПодсистемы.Свойства

4. В объекте – владельце свойств создать реквизит, значения которого определяют применение того или иного набора свойств для конкретного экземпляра объекта. Для справочника \_ДемоНоменклатура это реквизит ВидНоменклатуры типа СправочникСсылка.\_ДемоВидыНоменклатуры.

5. В модуле формы объекта реализовать обработчик ПриИзменении для элемента формы, редактирующего этот реквизит. Для справочника \_ДемоНоменклатура это обработчик:

&НаКлиенте

Процедура ВидНоменклатурыПриИзменении(Элемент)

ОбновитьЭлементыДополнительныхРеквизитов();

КонецПроцедуры

6. В процедуре ЗаполнитьНаборыСвойствОбъекта общего модуля УправлениеСвойствамиПереопределяемый вставить условие, заполняющее набор свойств для конкретного объекта. Например, для \_ДемоНоменклатура это следующее условие:

Процедура ЗаполнитьНаборыСвойствОбъекта(Объект, ТипСсылки, НаборыСвойств, СтандартнаяОбработка, КлючНазначения) Экспорт

…

Если ТипСсылки = Тип("СправочникСсылка.\_ДемоНоменклатура") Тогда

ЗаполнитьНаборСвойствПоВидуНоменклатуры(

Объект, ТипСсылки, НаборыСвойств);

КонецЕсли;

…

КонецПроцедуры

Процедура ЗаполнитьНаборСвойствПоВидуНоменклатуры(Номенклатура, ТипСсылки, НаборыСвойств)

Если ТипЗнч(Номенклатура) = ТипСсылки Тогда

Номенклатура = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(

Номенклатура, "ЭтоГруппа, ВидНоменклатуры");

КонецЕсли;

Если Номенклатура.ЭтоГруппа = Ложь Тогда

Строка = НаборыСвойств.Добавить();

Строка.Набор = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(

Номенклатура.ВидНоменклатуры, "НаборСвойств");

КонецЕсли;

КонецПроцедуры

Если справочник группирует объекты более чем одного типа, следует вписать в условие несколько типов, например:

Если ТипСсылки = Тип("СправочникСсылка.\_ДемоОшибки")

 ИЛИ ТипСсылки = Тип("СправочникСсылка.\_ДемоЗадачи") Тогда

ЗаполнитьНаборСвойствПоПроекту(

Объект, ТипСсылки, НаборыСвойств);

КонецЕсли;

7. В справочнике НаборыДополнительныхРеквизитовИСведений создать предопределенную группу с именем Справочник\_<ИмяОбъекта>, если объект – справочник: Документ\_<ИмяОбъекта>, если объект – документ, и т. д. Например, для справочника \_ДемоНоменклатура создана предопределенная группа Справочник\_\_ДемоНоменклатура. Наименование элемента при этом заполнять не требуется (оно будет заполнено автоматически на основании представления списка того объекта, к которому относится данный элемент).

8. Добавить в обработчике обновления информационной базы вызов процедуры УстановитьПараметрыНабораСвойств общего модуля УправлениеСвойствами для заполнения настроек добавленного набора свойств.

**Настройка объектов с несколькими объединяющимися наборами свойств**

Наборы свойств при этом должны объединяться в зависимости от тех или иных реквизитов объекта. Например, в справочнике партнеры могут быть введены клиенты, поставщики, конкуренты и партнеров, с которыми связывают прочие отношения. При этом один и тот же партнер может одновременно быть и тем, и другим, и третьим, а его дополнительные свойства должны динамически выводиться в зависимости от того, каких он типов.

В демонстрационной конфигурации этот вариант показан на справочнике \_ДемоПартнеры. В нем введены реквизиты Клиент, Поставщик, Конкурент, ПрочиеОтношения типа Булево, которые и определяют применение одного или сразу нескольких наборов свойств.

При этом подходе справочник имеет один предопределенный набор свойств для всех экземпляров объектов, а также несколько предопределенных наборов свойств, которые могут применяться к экземплярам данного объекта по тем или иным условиям.

Последовательность настройки такого объекта:

1. Принять решение по поводу наборов свойств объекта. Например, для справочника \_ДемоПартнеры демонстрационной конфигурации это четыре набора свойств: реквизиты Клиент, Поставщик, Конкурент, ПрочиеОтношения.

2. Выявить реквизиты объекта, значения которых определяют применение того или иного набора свойств для конкретного экземпляра объекта. Например, для справочника \_ДемоПартнеры демонстрационной конфигурации это реквизиты Клиент, Поставщик, Конкурент, ПрочиеОтношения.

3. В справочнике НаборыДополнительныхРеквизитовИСведений создать предопределенную группу с именем Справочник\_<ИмяОбъекта>, если объект – справочник; Документ\_<ИмяОбъекта>, если объект – документ, и т. д. Например, Справочник\_Контрагенты. Наименование элемента при этом заполнять не требуется (оно будет заполнено автоматически на основании представления списка того объекта, к которому относится данный элемент).

4. В этой предопределенной группе для каждого из наборов свойств создать предопределенный элемент с именами Справочник\_<ИмяОбъекта>\_<ИмяНабораСвойств>, например Справочник\_Партнеры\_Клиенты. Прим этом наименование элемента следует задавать краткое, например Клиенты; оно не должно содержать имя и тип объекта метаданных.

5. В этой предопределенной группе создать предопределенный элемент с именем Справочник\_<ИмяОбъекта>\_Общие и наименованием Общие, который будет содержать общие свойства для всех объектов.

6. В общем модуле УправлениеСвойствамиПереопределяемый в процедуре ЗаполнитьНаборыСвойствОбъекта следует вписать условие для данного типа объектов. Для справочника \_ДемоПартнеры это код вида:

Процедура ЗаполнитьНаборыСвойствОбъекта(Объект, ТипСсылки, НаборыСвойств, СтандартнаяОбработка) Экспорт

…

Если ТипСсылки = Тип("СправочникСсылка.\_ДемоПартнеры") Тогда

ЗаполнитьНаборыСвойствПартнера(Объект, ТипСсылки, НаборыСвойств);

КонецЕсли;

…

КонецПроцедуры

Процедура ЗаполнитьНаборыСвойствПартнера(Партнер, ТипСсылки, НаборыСвойств)

Если ТипЗнч(Партнер) = ТипСсылки Тогда

Объект = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(

Партнер, "Клиент, Конкурент, Поставщик, ПрочиеОтношения, ЭтоГруппа");

Иначе

Объект = Партнер;

КонецЕсли;

Если Объект.ЭтоГруппа = Ложь Тогда

Строка = НаборыСвойств.Добавить();

Строка.Набор = Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник\_Партнеры\_Общие;

Строка.Отображение = ОтображениеОбычнойГруппы.Линия;

Строка.ОтображатьЗаголовок = Истина;

Строка.Заголовок = НСтр("ru = 'Для всех партнеров'");

Если Объект.Клиент Тогда

Строка = НаборыСвойств.Добавить();

Строка.Набор = Справочники.НаборыДополнительныхРеквизитовИСведений.Справочник\_Партнеры\_Клиенты;

Строка.Отображение = ОтображениеОбычнойГруппы.Линия;

Строка.ОтображатьЗаголовок = Истина;

Строка.Заголовок = НСтр("ru = 'Для клиентов'");

КонецЕсли;

…

КонецПроцедуры

В приведенном примере проверяются значения реквизитов справочника Клиент, Поставщик, Конкурент, ПрочиеОтношения и наборы свойств добавляются в таблицу НаборыСвойств. В поле Набор устанавливается ссылка на набор свойств, а в остальные поля могут быть установлены значения оформления набора в форме.

7. В форме объекта необходимо реализовать обработчики ПриИзменении для тех реквизитов, которые определят состав наборов свойств, применяемых для данного экземпляра объекта. Например, для формы справочника \_ДемоПартнеры это обработчики вида:

&НаКлиенте

Процедура КлиентПриИзменении(Элемент)

// СтандартныеПодсистемы.Свойства

ОбновитьЭлементыДополнительныхРеквизитов();

// Конец СтандартныеПодсистемы.Свойства

КонецПроцедуры

**Настройка дополнительных характеристик объектов метаданных**

Для каждого объекта конфигурации со свойствами необходимо открыть и заполнить диалог редактирования дополнительных характеристик.

Если для объекта настроены дополнительные реквизиты:

Таблица 3.108.

|  |  |  |
| --- | --- | --- |
| Поле ключа | Поле отбора видов | Значение отбора видов |
| Виды характеристик | | |
| Справочник.НаборыДополнительныхРеквизитовИСведений.ТабличнаяЧасть.ДополнительныеРеквизиты | | |
| Свойство | Ссылка | <Предопределенный элемент справочника НаборыДополнительныхРеквизитовИСведений> |
| Значения характеристик | | |
| Справочник.<Имя объекта со свойствами>.ТабличнаяЧасть.ДополнительныеРеквизиты | | |
| Ссылка | Свойство | Значение |

Если для объекта настроены дополнительные сведения:

Таблица 3.109.

|  |  |  |
| --- | --- | --- |
| Поле ключа | Поле отбора видов | Значение отбора видов |
| Виды характеристик | | |
| Справочник.НаборыДополнительныхРеквизитовИСведений.ТабличнаяЧасть.ДополнительныеСведения | | |
| Свойство | Ссылка | <Предопределенный элемент справочника НаборыДополнительныхРеквизитовИСведений> |

Таблица 3.110.

|  |  |  |
| --- | --- | --- |
| Значения характеристик | | |
| Поле объекта | Поле вида | Поле значения |
| РегистрСведений.ДополнительныеСведения | | |
| Объект | Свойство | Значение |

где <Предопределенный элемент (группа) справочника НаборыДополнительныхРеквизитовИСведений> – предопределенный элемент (группа), созданный на предыдущем этапе.

**Отключение неиспользуемых наборов свойств**

В случае если объект, использующий набор свойств, отключен по функциональной опции, имеется возможность отключить неиспользуемый набор свойств. Для этого можно воспользоваться свойством Используется набора свойств. При установке значения свойства Используется в значение Ложь набор свойств перестает отображаться в форме списка, также свойства перестают отображаться в форме объекта-владельца. Для отключения неиспользуемого набора свойств необходимо:

* ● Написать обработчик обновления, отключающий неиспользуемые наборы свойств при переходе на новую версию. Пример кода обработчика:

ПараметрыНабора = УправлениеСвойствами.СтруктураПараметровНабораСвойств();

ПараметрыНабора.Используется = ПолучитьФункциональнуюОпцию("ИспользоватьВнешнихПользователей");

УправлениеСвойствами.УстановитьПараметрыНабораСвойств("Справочник\_ВнешниеПользователи", ПараметрыНабора);

* ● Добавить аналогичный код в событие при изменении значения функциональной опции. См. пример в подписке \_ДемоОбновитьИспользованиеВнешнихПользователей.

**Размещение в командном интерфейсе**

Для использования подсистемы необходимо разместить в командном интерфейсе объект метаданных:

* ● Справочник НаборыДополнительныхРеквизитовИСведений – для работы по просмотру и редактированию состава свойств (редактором состава свойств и администратором).

В случае если в конфигурации не используется подсистема «Настройки программы», в рабочем месте администратора программы необходимо разместить константы:

* ● ИспользоватьДополнительныеРеквизитыИСведения – для включения и выключения подсистемы;
* ● ИспользоватьОбщиеДополнительныеЗначения – для включения и выключения команды добавления свойств с общим списком значений (по образцу);
* ● ИспользоватьОбщиеДополнительныеРеквизитыИСведения – для включения и выключения команды добавления общих свойств.

См. пример в форме ОбщиеНастройки обработки ПанельАдминистрированияБСП.

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы следует использовать роли:

Таблица 3.111.

| № | Роли и их назначение |
| --- | --- |
| 1. | БазовыеПраваБСП  Чтение наборов свойств и дополнительных свойств. Просмотр значений свойств объектов |
| 2. | ЧтениеДополнительныхСведений  Чтение дополнительных сведений.  При совместном использовании с подсистемой «Управление доступом» имеется возможность ограничивать доступ пользователей к отдельным дополнительным сведениям. См. раздел «[Особые случаи внедрения подсистем](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_особые_случаи_внедрения)» |
| 3. | ИзменениеДополнительныхСведений  Добавление и изменение дополнительных сведений.  При совместном использовании с подсистемой «Управление доступом» имеется возможность ограничивать доступ пользователей к отдельным дополнительным сведениям. См. раздел «[Особые случаи внедрения подсистемы](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_особые_случаи_внедрения)» |
| 4. | ДобавлениеИзменениеДополнительныхРеквизитовИСведений  Добавление и изменение свойств, наборов свойств, значений свойств объектов |
| 5. | ПолныеПрава (из подсистемы «Базовая функциональность»)  Включение и отключение использования свойств. Удаление помеченных на удаление объектов подсистемы |

Для просмотра и редактирования дополнительных реквизитов конкретных объектов требуются роли для просмотра и редактирования самих объектов-владельцев дополнительных реквизитов.

Пример настройки прав доступа пользователей:

Таблица 3.112.

| № | Группа пользователей и ее функции | Состав ролей |
| --- | --- | --- |
| 1. | Ответственный за настройку состава дополнительных свойств | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ДобавлениеИзменениеДополнительныхРеквизитовИСведений,  ● ЗапускТонкогоКлиента (из подсистемы «Базовая функциональность») |
| 2. | Просмотр значений дополнительных сведений объектов информационной базы | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ЧтениеДополнительныхСведений,  ● ЗапускТонкогоКлиента (из подсистемы «Базовая функциональность») |
| 3. | Редактирование значений дополнительных сведений объектов информационной базы | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ИзменениеДополнительныхСведений,  ● ЗапускТонкогоКлиента (из подсистемы «Базовая функциональность») |

**Особые случаи внедрения подсистемы**

* ● [Внедрение подсистемы «Свойства» без подсистемы «Взаимодействия»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«свойства»).
* ● [Внедрение подсистемы «Свойства» без подсистемы «Работа с файлами»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«свойства»_1).
* ● [Внедрение подсистем «Свойства» и «Управление доступом»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистем_«свойства»_1).

**Использование при разработке конфигурации**

При создании новых прикладных объектов метаданных нужно повторно выполнять соответствующую часть процедуры настройки, описанной выше.

**Переименование предопределенных элементов справочника «Наборы дополнительных реквизитов и сведений»**

При изменении наименования предопределенного элемента справочника НаборыДополнительныхРеквизитовИСведений требуется добавить оперативный обработчик обновления, в котором вызвать процедуру ОбновитьНаименованияНаборовИСвойств модуля УправлениеСвойствами.

При изменении представления объекта метаданных, который соответствует предопределенному элементу, обработчик обновления добавлять не требуется.

**Настройка обмена данными**

Для настройки обмена данными следует руководствоваться общими правилами.

В планы обмена распределенной информационной базы (РИБ) рекомендуется включать все объекты метаданных подсистемы.